Logo POVRay...
Instrucciones para "RBDJ.inc" v1.0

Donación de Rafael Angel Campos Vargas, en setiembre del 2011, a la Biblioteca de objetos de POV-Ray.  Este proyecto se encuentra actualmente inscrito con la patente LGPL;  para libre uso comercial y no comercial del software.

CC-GNU LGPL
The primary purpose of this collection is to make items publicly available under a common license that permits use, modification and re-distribution. To support this contributions are donated to the collection with consent for their use under the terms of the Creative Commons - Lesser General Purpose License (CC-GNU LGPL).
Chris Bartlett 2007
Los fractales fueron tomados de la biblioteca scene/objects de la distribución PovRay 3.6.  Siendo entidades matemáticas para demostración, asumo que no habrá inconvenientes...  Los archivos pertinentes no indican autor. 


La versión actual v1.0 de "RBDJ.inc" (RecibienteBasureroDeJulio) crea un basurero de fractales.  Contiene además macros para facilitar el diseño de pequeños botaderos.  El algoritmo permite incorporar basuras diseñadas por el usuario.  Lamentablemente no es compatible con POV-Ray 3.1.

Indice de página:

  1. Instalación de Archivos
  2. Instrucciones básicas
  3. Características del objeto
  4. Modificadores
  5. Notas y Advertencias
  6. Sugerencias de modificación
  7. Sobre LibreN3D

Instalación de Archivos

El procedimiento siguiente es completamente optativo, corresponde simplemente al estándard de la Biblioteca de objetos POV-Ray.
  1. Cree el subdirectorio "ObjectCollections".  Se sugiere un subdirectorio del folder POV-Ray, creado por el instalador en algunas versiones en la sección de documentos o bien en la de código.
  2. Copie los archivos "RBDJ.inc" y "RBDJ_Obj.inc" en dicho subdirectorio;  únicamente éstos dos son necesarios.  Opcionalmente podría colocar la documentación y demás en el mismo subdirectorio, el estándar ha sido diseñado para evitar problemas de compatibilidad.
  3. Actualice los archivos buscados por POV-Ray, en algún archivo ini pertinente.  Por ejemplo "POVRay.ini";  agregue el comando Library_Path="C:\FDOS\POVRAY31\ObjectCollections"; o el que corresponda a su sistema operativo.  POV-Ray ofrece muchas formas de realizar esto.  Si no sabe cómo, probablemente convenga leer el manual de referencia en la sección "Command-line options".   Cada sistema operativo presenta sus propias variantes.
Nota:  El archivo de prueba "RBDJ.pov" puede ejecutarse sin ningún proceso de instalación.  Unicamente debería estar ubicado en el mismo folder que "RBDJ.inc" y "RBDJ_Obj.inc".


Instrucciones básicas

Basurero
Muy fácil de usar, tan simple como incluir el archivo y ubicar el objeto.  Se define una versión del objeto en posición basal, mediante macro default.

El siguiente ejemplo recurre a la macro default, colocando al basurero en posición base.

    #include "stdinc.inc"
    #include "stdcam.inc"
    #include "RBDJ.inc"
    
    object      {
      RBDJ_Basurero(1000)
      translate         < -1.625,  0.725,-3.5   >
    }
La macro principal recibe únicamente un parametro.
    #macro RBDJ_Basurero( Semilla )
Semilla :
Parametro de aleatoriedad ( misma semilla, mismo basurero ).
Otras macros útiles para diseño de pequeños botaderos de basura, serían las siguientes:
  #macro RBDJ_CirculoBasura
        ( Semilla, SelectorMacro, Centro, Radio, Delta, 
                PuntoCustom, PuntoS )
Semilla :
Parametro de aleatoriedad ( misma semilla, mismo basurero ).
SelectorMacro :
Valor para elegir la macro a utilizar.
RBDJ_SuperficieCustom (definida por el usuario)
RBDJ_SuperficiePlana (plano de altura 0)
RBDJ_SuperficieRBDJ1 (curva default)
Centro :
Centro como Vector3D del círculo de basuras.  Al final de la macro se aplica translate Centro.
Radio :
Radio del círculo de basura.
Delta :
Separacion media entre basura y basura en el plano XY.
PuntoCustom :
Valor variado a pasar a una macro diseñada por el usuario.  Puede usar cero cuando no lo requiera.
PuntoS :
Máxima distancia aleatoria para equivocar la posición de la basura.
También se ofrece una variante rectangular de la macro anterior.
  #macro RBDJ_RectanguloBasura
        ( Semilla, SelectorMacro, 
                XMin, XMax, DeltaX, YMin, YMax, DeltaY, PuntoS ) 
Semilla :
Parametro de aleatoriedad ( misma semilla, mismo basurero ).
SelectorMacro :
Valor para elegir la macro a utilizar.
RBDJ_SuperficieCustom (definida por el usuario)
RBDJ_SuperficiePlana (plano de altura 0)
RBDJ_SuperficieRBDJ1 (curva default)
XMin :
Posicion X mínima del rectángulo.
XMax :
Posicion X máxima del rectángulo.
DeltaX :
Separación X de basura y basura.
YMin :
Posicion Y mínima del rectángulo.
YMax :
Posicion Y máxima del rectángulo.
DeltaY :
Separación Y de basura y basura.
PuntoCustom :
Valor variado a pasar a una macro diseñada por el usuario.  Puede usar cero cuando no lo requiera.
PuntoS :
Máxima distancia aleatoria para equivocar la posición de la basura.
El siguiente ejemplo recurre a la macro de para basura circular:

    #include "stdinc.inc"
    #include "stdcam.inc"
    #include "RBDJ.inc"
    
    object       {
      RBDJ_CirculoBasura( 2100, RBDJ_SuperficiePlana, 
		<0,0,0>, 0.5, 0.05, 0, 0.2 )
      translate         < -1.625,  0.725,-3.5   >
    }
Y este otro ejemplo recurre a la macro rectangular:

    #include "stdinc.inc"
    #include "stdcam.inc"
    #include "RBDJ.inc"
    
    object       {
      RBDJ_RectanguloBasura( 2100, RBDJ_SuperficiePlana, 
                -0.5, 0.5, 0.02, -0.5,0.5, 0.02, 0, 0.5 )
      translate         < -1.625,  0.725,-3.5   >
    }

Características del objeto

Mis dibujos están en unidades L (Lisa).  1 L equivale a 0.055063 pulgadas definido como 0.001 para POVRAY.  El basurero default tiene las siguientes características:
    Altura                   = 715*L
    RadioBasurero            = 200*L
En posicion basal descansa en el origen del plano XZ, orientado hacia Y+.

Las diferentes basuras se encuentran identificadas con un número clave, que puede obtenerse con la siguiente macro.

  #macro RBDJ_ObtenerUbicacion ( NumeroElegido, Clave )
NumeroElegido :
Variable de salida que da un número clave para accesar un objeto basura.  Posición en el arreglo de objetos.
Clave :
Valor clave de identificación de basura.  Los valores de entrada en la versión actual son RBDJ_A1..RBDJ_A10.
Se definen las siguientes variables útiles para la identificación de basuras.
RBDJ_TotalArticulos
Define el total de tipos de basuras en el arreglo de basuras.
RBDJ_ArregloArticulos
Arreglo de objetos que se utilizan como basura.
RBDJ_DescriptorArticulos
Describe los artículos en el arreglo principal.  Los valores se accesan o modifican como la segunda dimensión del arreglo.
RBDJ_IndiceIdentificador
Para identificar al objeto.
RBDJ_IndiceActivo
Con off el objeto no se toma en cuenta.
RBDJ_IndiceProbabilidad
Considere un peso probabilístico, las basuras del dibujo tiene pesos entre 0.05 y 3.
RBDJ_IndiceScale
Valor scale para ajustar el objeto.
RBDJ_IndiceVarScale
Introduce variabilidad en scale (su magnitud se aplica en el objeto original).
RBDJ_IndiceTextura
Indice para buscar el material en RBDJ_ArregloMaterial.
RBDJ_TotalMaterial
Define el total de materiales definidos en el arreglo.
RBDJ_ArregloMaterial
Define una lista de materiales a aplicar en las basuras.
Es posible agregar objetos a la lista predefinida, para ello debería seguirse el siguiente procedimiento.
  1. Declare un objeto que sirva de basura y el material respectivo como variables #declare.
  2. Asigne el objeto como nuevo elemento del arreglo de objetos RBDJ_ArregloArticulos.  El nuevo elemento tiene índice RBDJ_TotalArticulos.
  3. Asigne el material creado como nuevo elemento del arreglo de materiales RBDJ_ArregloMaterial.  El nuevo elemento tiene índice RBDJ_TotalMaterial.
  4. Actualice todos los campos de RBDJ_DescriptorArticulos con el indice RBDJ_TotalArticulos.  Es importante declarar todos los campos.
  5. Se recomienda definir un valor Clave para su Artículo por ejemplo ClaveBasuraPesonal = 10000.  Esta version tiene 10 objetos, asi que si utiliza valores mayores de 10000 no debería haber problemas.
  6. Aumente en una unidad RBDJ_TotalArticulos, y RBDJ_TotalMaterial.

Si desea sustituir alguna basura, que no es apropiada para la época del dibujo, puede valerse del siguiente proceso.

    RBDJ_ObtenerUbicacion(MyDato,RBDJ_A9)
    RBDJ_DescriptorArticulos[MyDato][RBDJ_IndiceActivo] = off;
    RBDJ_ObtenerUbicacion(MyDato,ClaveBasuraPersonal)
    RBDJ_DescriptorArticulos[MyDato][RBDJ_IndiceActivo] = on;
El siguiente ejemplo ilustra como agregar esferas rojas a las basuras.
    #include "stdinc.inc"
    #include "stdcam.inc"
    #include "RBDJ.inc"
    
    #declare BasuraPersonal      = sphere { 0, 1 }
    #declare MaterialPersonal    = material {texture {pigment {Red}}}
    #declare ClaveBasuraPersonal = 10000;
    #declare RBDJ_ArregloArticulos
                 [ RBDJ_TotalArticulos ] = BasuraPersonal;
    #declare RBDJ_ArregloMaterial
                 [ RBDJ_TotalMaterial ]   = MaterialPersonal;
    #declare RBDJ_DescriptorArticulos[ RBDJ_TotalArticulos ]
                 [ RBDJ_IndiceIdentificador ]     = ClaveBasuraPersonal;
    #declare RBDJ_DescriptorArticulos[ RBDJ_TotalArticulos ]
                 [ RBDJ_IndiceActivo        ]     = on;
    #declare RBDJ_DescriptorArticulos[ RBDJ_TotalArticulos ]
                 [ RBDJ_IndiceProbabilidad  ]     = 20.0;
    #declare RBDJ_DescriptorArticulos[ RBDJ_TotalArticulos ]
                 [ RBDJ_IndiceScale         ]     = 0.025;
    #declare RBDJ_DescriptorArticulos[ RBDJ_TotalArticulos ]
                 [ RBDJ_IndiceVarScale      ]     = 0.01;
    #declare RBDJ_DescriptorArticulos[ RBDJ_TotalArticulos ]
                 [ RBDJ_IndiceTextura       ]     = RBDJ_TotalMaterial; 
    #declare RBDJ_TotalArticulos         = RBDJ_TotalArticulos+1; 
    #declare RBDJ_TotalMaterial          = RBDJ_TotalMaterial+1;
    object       {
      RBDJ_RectanguloBasura( 2100, RBDJ_SuperficiePlana, 
                -0.5, 0.5, 0.02, -0.5,0.5, 0.02, 0, 0.5 )
      translate         < -1.625,  0.725,-3.5   >
    }

Se definen las siguientes texturas base, que no deberían modificarse.  Para su correcta modificación consultar la sección Modificadores.

RBDJ_TexturaBasurero
Define la textura a aplicar en el basurero principal.
RBDJ_TexturaFondoBasurero
Define la textura del fondo del basurero.

Modificadores

Se le permite al usuario optar por una macro de ubicación de su propio diseño.  Su formato es el siguiente
    #macro RBDJ_MacroCustom
           ( AlturaSuperficie, BanderaPertenece, XX, YY, VectorA )
      #local AlturaSuperficie 	= 0.0;
      #local BanderaPertenece  	= true;
    #end
AlturaSuperficie
Altura Z+ del punto de basura como salida.
BanderaPertenece
Si devuelve false como salida, la basura no se dibuja.
XX
Posición X de entrada para dibujar la basura.
YY
Posición Y de entrada para dibujar la basura.
VectorA
Parametro adicional para utilizar a gusto del usuario.
Los valores XX y YY no toman en cuentra el translate que se aplica al arreglo de basuras circular.  El siguiente es un ejemplo de diseño de la macro custom.
    #include "stdinc.inc"
    #include "stdcam.inc"
    #include "RBDJ.inc"
    #macro RBDJ_MacroCustom
           ( AlturaSuperficie, BanderaPertenece, XX, YY, VectorA )
      #local AlturaSuperficie 	        = 1-2*XX*XX; 
      #if ( XX*XX+YY*YY > 0.1 )
        #local BanderaPertenece  	= true;
      #else
        #local BanderaPertenece         = false;
      #end
    #end
    object       {
      RBDJ_RectanguloBasura( 2100, RBDJ_SuperficieCustom, 
                -0.5, 0.5, 0.05, -0.5,0.5, 0.05, 0, 0 )
      translate         < -1.625,  0.725,-3.5   >
    }
La siguiente es la lista de los modificadores permitidos en la unidad (cuando se indica, son valores default).

    #declare RBDJ_NoBasura				= false;
Si se activa con "true" el basurero se dibuja vacío.

    #declare RBDJ_DefaultTexturaBasurero		= texture { ... }
Permite cambiar la textura default a aplicar al basurero.

    #declare RBDJ_DefaultTexturaFondoBasurero		= texture { ... }
Permite cambiar la textura default a aplicar al fondo del basurero.

A manera de ejemplo del uso de los modificadores:

    #include "stdinc.inc"
    #include "stdcam.inc"
    #include "textures.inc"
    #include "RBDJ.inc" 
    #declare RBDJ_NoBasura      = true;
    #declare RBDJ_DefaultTexturaBasurero        = texture       {
      average
      texture_map        {
        [ 0.9 PinkAlabaster              ] 
        [ 0.1 RBDJ_TexturaBasurero       ]
      }
    }
    #declare RBDJ_DefaultTexturaFondoBasurero   = texture       {
      average
      texture_map        {
        [ 0.9 PinkAlabaster              ] 
        [ 0.1 RBDJ_TexturaFondoBasurero  ]
      }
    }
    
    object       {
      RBDJ_Basurero( 2100 ) 
      rotate            -30*x
      translate         < -1.625,  0.725, -3.5   >
    }

Notas y Advertencias

Por causas desconocidas, la diferencia dentro del basurero resulta defectuosa, de forma que las basuras perforan el recipiente hasta el exterior de la estructura.  Este efecto desaparece por supuesto, en el basurero vacío;  y puede mitigarse con bajos valores de aleatoriedad.

La ejecución de los botaderos, es bastante lenta.  Podría ser útil desactivar las basuras, y sustituirlas por esferas simples al ubicar objetos.

Muchas basuras son semitransparentes, por lo que seguramente requerirá varias capas para lograr efectos de mayor realismo.


Sugerencias de modificación


Sobre LibreN3D

Algo hace falta En la actualidad dedico casi unas dos horas todos los días, para desarrollar el programa de animación LibreN3D con el compilador FreePascal para FreeDOS.  El objetivo era en un origen, realizar animaciones de "baja" calidad, con progreso lento y paulatino. Desconocía en ese entonces del programa POV-Ray.  Creo que con ayuda de dicho proyecto, podría lograr mucho mejores resultados desde un principio.  Confío que para el 2020 pueda lograr animaciones completas de aceptable calidad.   En la actualidad, intento agregarle características elásticas a los objetos.  He tenido numerosos retrasos, así que todavía no funciona.  Lo siento...(27/setiembre/2011), pero me siento muy seguro de que pronto lo lograré.  De momento, no tiene interface con el usuario, pero se encuentra en desarrollo como intérprete de renglón al estilo DOS.

Me sería de muchísima ayuda, que el grupo POV-Ray siguiera desarrollando la versión para DOS.   Los siguientes son enlaces que podrían ser de utilidad para el interesado en los proyectos FreePascal y FreeDOS.   Lamentablemente en la actualidad son altamente inestables, debido probablemente a dificultades con la adaptación al modo de 64 bits.
Logo FreeDOS...
Descarga sistema operativo FreeDOS
Logo FreePascal...
Descarga compilador FreePascal