Logo POVRay...
Instrucciones para "MCSI.inc" v1.0

Donación de Rafael Angel Campos Vargas, en el año 2012, a la Biblioteca de objetos de POV-Ray.  Este proyecto se encuentra actualmente inscrito con la patente LGPL;  para libre uso comercial y no comercial del software.

CC-GNU LGPL
The primary purpose of this collection is to make items publicly available under a common license that permits use, modification and re-distribution. To support this contributions are donated to the collection with consent for their use under the terms of the Creative Commons - Lesser General Purpose License (CC-GNU LGPL).
Chris Bartlett 2007

La versión actual v1.0 de "MCSI.inc" (MuebleCocinaSuperiorInferior) dibuja un mueble de cocina de superficie impermeable para acomodar ingredientes, electrodomésticos y otros recursos culinarios.  El paquete únicamente incluye el mueble, y algunas macros que permiten modificar fácilmente sus características básicas.  Es compatible con PovRay 3.1.

Indice de página:

  1. Instalación de Archivos
  2. Instrucciones básicas
  3. Características del objeto
  4. Modificadores
  5. Notas y Advertencias
  6. Sugerencias de modificación
  7. Sobre LibreN3D

Instalación de Archivos

El procedimiento siguiente es completamente optativo, corresponde simplemente al estándard de la Biblioteca de objetos POV-Ray.
  1. Cree el subdirectorio "ObjectCollections".  Se sugiere un subdirectorio del folder POV-Ray, creado por el instalador en algunas versiones en la sección de documentos o bien en la de código.
  2. Copie el archivo "MCSI.inc" en dicho subdirectorio;  únicamente éste es necesario.  En cuanto a la documentación y demás puede colocarla si desea en el mismo subdirectorio, el estándar ha sido diseñado para evitar problemas de compatibilidad.
  3. Actualice los archivos buscados por POV-Ray, en algún archivo ini pertinente.  Por ejemplo "POVRay.ini";  agregue el comando Library_Path="C:\FDOS\POVRAY31\ObjectCollections"; o el que corresponda a su sistema operativo.  POV-Ray ofrece muchas formas de realizar esto.  Si no sabe cómo, probablemente convenga leer el manual de referencia en la sección "Command-line options".   Cada sistema operativo presenta sus propias variantes.
Nota:  El archivo de prueba "MCSI.pov" puede ejecutarse sin ningún proceso de instalación.  Unicamente debería estar ubicado en el mismo folder que "MCSI.inc".


Instrucciones básicas

Mueble de cocina
Muy fácil de usar, tan simple como incluir el archivo y ubicar el objeto.  El siguiente ejemplo recurre a la macro default, colocando al objeto en posición base.

    #include "stdinc.inc"
    #include "stdcam.inc"
    #include "MCSI.inc"
    
    object      {
      MCSI_MuebleCocina( on, 0, 0, 0, 0, 0, 0 )
      translate <-1.5, 0.0, -3.0>
    }

Los parámetros de la macro principal serían los siguientes:

    #macro MCSI_MuebleCocina
        ( VisibleSuperior, Angulo1, Angulo2, 
		Angulo3, Angulo4, Angulo5, Angulo6 )
VisibleSuperior :
"on" dibuja el mueble superior, "off" no lo dibuja.
Angulo1 :
Angulo de apertura para primera puertecilla superior de izquierda a derecha.  Cero para totalmente cerrada.
Angulo2 :
Angulo de apertura para segunda puertecilla superior de izquierda a derecha.  Cero para totalmente cerrada.
Angulo3 :
Angulo de apertura para tercera puertecilla superior de izquierda a derecha.  Cero para totalmente cerrada.
Angulo4 :
Angulo de apertura para cuarta puertecilla superior de izquierda a derecha.  Cero para totalmente cerrada.
Angulo5 :
Angulo de apertura para primera puertecilla inferior de izquierda a derecha.  Cero para totalmente cerrada.
Angulo6 :
Angulo de apertura para segunda puertecilla inferior de izquierda a derecha.  Cero para totalmente cerrada.

La siguiente macro permite dibujar el mueble superior con mucho mayor control sobre sus características.  El objeto requiere aplicar translate 1026*L*y, para ubicarlo en la posición default.

    #macro MCSI_MuebleCocinaSuperiorClavos
        ( Alto, Frente, Profundidad, GruesoLateral, GruesoNormal,
          Pisos, Compartimientos, FraccionAgarradera, FraccionAgarradera2,
          DoblePuerta, PaqueteAngular,
          TexturaMadera, TexturaMaderaBarata, TexturaAgarradera )
Alto :
Alto del mueble superior.  Default es 286*L.
Frente del mueble superior :
Frente del mueble superior.  Default es 1080*L.
Profundidad :
Referencia para la profundidad del mueble superior.  Default es 219*L.
GruesoLateral :
Referencia para los bordes laterales de las puertas en los compartimientos.  Default es 21*L.
GruesoNormal :
Referencia para el grueso de madera interior.  Default es 8*L.
Pisos :
Total de pisos interiores.  Default es 2.
Compartimientos :
Total de compartimientos horizontales.  Default es 2.
FraccionAgarradera :
Valor fraccionario para ubicar a lo alto la agarradera en la puertecilla.  Cero no la dibuja.  Default es 0.5.
FraccionAgarradera2 :
Valor fraccionario para controlar el tamaño de la agarradera.  Default es 1.0.
DoblePuerta :
"on" utiliza puertas dobles para cada compartimiento;  "off" utiliza una puerta sencilla.
PaqueteAngular :
Consiste en un tipo array [Compartimientos][2].  Su estructura depende del parámetro DoblePuerta. 
DoblePuerta "on"
PaqueteAngular[C][0] :
Angulo de apertura, a partir de cero, de la puerta izquierda del compartimiento C.
PaqueteAngular[C][1] :
Angulo de apertura, a partir de cero, de la puerta derecha del compartimiento C.
DoblePuerta "off"
PaqueteAngular[C][0] :
Angulo de apertura, a partir de cero, de la puerta del compartimiento C.
PaqueteAngular[C][1] :
"on" agarradera a la derecha, "off" agarradera a la izquierda.
TexturaMadera :
Textura principal del mueble.  Default es MCSI_DefaultTexturaMadera.
TexturaMaderaBarata :
Textura del interior del mueble.  Default es MCSI_DefaultTexturaMaderaBarata.
TexturaAgarrradera :
Textura metalizada para la agarradera y los ejes de las bisagras.  Default es MCSI_DefaultTexturaAgarradera.

La siguiente macro permite dibujar el mueble inferior con mucho mayor control sobre sus características.

    #macro MCSI_MuebleCocinaInferiorClavos
        ( AltoB, FrenteB, ProfundidadB, GruesoLateralB, GruesoNormalB,
          AltoBaseB, AltoImpermeable,
          PisosB, CompartimientosB, FraccionAgarradera, FraccionAgarradera2,
          DoblePuerta, PaqueteAngularB,
          TexturaMadera, TexturaMaderaBarata, 
	  TexturaAgarradera, TexturaImpermeable )
AltoB :
Referencia para el alto del mueble inferior.  Default es 536*L.
Frente :
Referencia para frente del mueble inferior.  Default es 1080*L.
ProfundidadB :
Referencia para la profundidad del mueble inferior.  Default es 357*L.
GruesoLateralB :
Referencia para los bordes laterales de las puertas en los compartimientos.  Default es 50*L.
GruesoNormalB :
Referencia para el grueso de madera interior.  Default es 8*L.
AltoBaseB :
Alto de las patas soporte.  Default es 89*L.
AltoImpermeable :
Referencia para el alto de la cubierta impermeable.  Default es 71*L.
PisosB :
Total de pisos interiores.  Default es 2.
CompartimientosB :
Total de compartimientos horizontales.  Default es 2.
FraccionAgarradera :
Valor fraccionario para ubicar a lo alto la agarradera en la puertecilla.  Cero no la dibuja.  Default es 0.6.
FraccionAgarradera2 :
Valor fraccionario para controlar el tamaño de la agarradera.  Default es 0.75.
DoblePuerta :
"on" utiliza puertas dobles para cada compartimiento;  "off" utiliza una puerta sencilla.
PaqueteAngularB :
Consiste en un tipo array [Compartimientos][2].  Su estructura depende del parámetro DoblePuerta. 
DoblePuerta "on"
PaqueteAngularB[C][0] :
Angulo de apertura, a partir de cero, de la puerta izquierda del compartimiento C.
PaqueteAngularB[C][1] :
Angulo de apertura, a partir de cero, de la puerta derecha del compartimiento C.
DoblePuerta "off"
PaqueteAngularB[C][0] :
Angulo de apertura, a partir de cero, de la puerta del compartimiento C.
PaqueteAngularB[C][1] :
"on" agarradera a la derecha, "off" agarradera a la izquierda.
TexturaMadera :
Textura principal del mueble.  Default es MCSI_DefaultTexturaMadera.
TexturaMaderaBarata :
Textura del interior del mueble.  Default es MCSI_DefaultTexturaMaderaBarata.
TexturaAgarrradera :
Textura metalizada para la agarradera y los ejes de las bisagras.  Default es MCSI_DefaultTexturaAgarradera.
TexturaImpermeable :
Textura a aplicar a la cubierta superior del mueble inferior.  Default es MCSI_DefaultTexturaImpermeable.

En el siguiente ejemplo, procedemos a dibujar el mismo objeto establecido anteriormente:

    #include "stdinc.inc"
    #include "stdcam.inc"
    #include "MCSI.inc"
    
    #declare Pisos                 = 2;
    #declare Compartimientos       = 2;
    #declare ArregloAngular        = array[Compartimientos][2] 
                { {0,0},{0,0} }
    #declare PisosB                = 2;
    #declare CompartimientosB      = 2;
    #declare ArregloAngularB       = array[CompartimientosB][2] 
                { {0,on},{0,off} }
    
    union       {
      object      {
        MCSI_MuebleCocinaSuperiorClavos
          ( 0.286, 1.080, 0.219, 0.021, 0.008,
            Pisos, Compartimientos, 0.5, 1.0, on, ArregloAngular,
            MCSI_DefaultTexturaMadera, MCSI_DefaultTexturaMaderaBarata,
            MCSI_DefaultTexturaAgarradera )
        translate         1.026*y
      }
      object      {
        MCSI_MuebleCocinaInferiorClavos
          ( 0.536, 1.080, 0.357, 0.050, 0.008,
            0.089, 0.071,
            PisosB, CompartimientosB, 0.6, 0.75,
            off, ArregloAngularB,
            MCSI_DefaultTexturaMadera, MCSI_DefaultTexturaMaderaBarata,
            MCSI_DefaultTexturaAgarradera, MCSI_DefaultTexturaImpermeable )
      }                            
      translate <-1.5, 0.0, -3.0>
    }          


Características del objeto

Mis dibujos están en unidades L (Lisa).  1 L equivale a 0.055063 pulgadas definido como 0.001 para POVRAY.  El objeto default tiene las siguientes características:
    Alto total                      : 1312*L
    Alto estante superior           :  286*L
    Altura estante superior         : 1026*L
    Alto estante inferior           :  706*L
    Frente estante superior         : 1080*L
    Frente estante inferior         : 1134*L
    Profundidad estante superior    :  219*L
            con agarradera          :  234*L
    Profundidad estante inferior    :  398*L
            con agarradera          :  419*L
El mueble se dibuja sobresaliendo hacia Z- sobre el plano YZ que hace de pared.  Se asume el mueble empotrado o en contacto con la pared;  aunque la parte posterior del mueble inferior se desplaza hacia adelante unos 10*L para dar espacio a la cubierta impermeable.

Se generan las siguientes declaraciones que no deberían modificarse.  Para su correcta modificación consultar la sección Modificadores.

MCSI_ArregloPisosInferiores[Compartimientos][Pisos+1]
Se declara con cada llamado a las macros MCSI_MuebleCocina() y MCSI_MuebleCocinaInferiorClavos().  Es un arreglo de vectores 3D, que facilita ubicar objetos al interior de los compartimientos.  Calcula una posición cercana al centro, ligeramente corrida hacia atrás.  Su orden es de izquierda a derecha y de abajo hacia arriba.  El vector MCSI_ArregloPisosInferior[C][Pisos] ubica la parte superior del mueble, en línea con el compartimiento C respectivo.
MCSI_ArregloPisosSuperior[Compartimientos][Pisos+1]
Se declara con cada llamado a las macros MCSI_MuebleCocina() y MCSI_MuebleCocinaSuperiorClavos().  Es un arreglo de vectores 3D, que facilita ubicar objetos al interior de los compartimientos.  Calcula una posición cercana al centro, ligeramente corrida hacia atrás.  Su orden es de izquierda a derecha y de abajo hacia arriba.  El vector MCSI_ArregloPisosSuperior[C][Pisos] ubica la parte superior del mueble, en línea con el compartimiento C respectivo.
MCSI_ArregloPisos[Compartimientos][Pisos+1]
Se declara con cada llamado a la macro MCSI_MuebleCocinaSuperiorClavos().  Es un arreglo de vectores 3D, que facilita ubicar objetos al interior de los compartimientos.  Calcula una posición cercana al centro, ligeramente corrida hacia atrás.  Su orden es de izquierda a derecha y de abajo hacia arriba.  El vector MCSI_ArregloPisos[C][Pisos] ubica la parte superior del mueble, en línea con el compartimiento C respectivo.
MCSI_TexturaMadera
Textura principal del mueble.
MCSI_TexturaMaderaBarata
Textura del interior del mueble.
MCSI_TexturaAgarradera
Textura de las agarraderas y bisagras.
MCSI_TexturaImpermeable
Textura a aplicar a la cubierta impermeable superior del mueble inferior.

El siguiente ejemplo ubica una esfera coloreada en cada estante.

    #include "stdinc.inc"
    #include "stdcam.inc"
    #include "MCSI.inc"
                     
    union               {
      object            {
        MCSI_MuebleCocina(on,90,90,90,90,90,90)               
      }
      #local C        = 0;
      #while ( C < 2 )
        #local D      = 0;
        #while ( D < 3 )
          sphere      {
            0 , 0.04
            translate 0.04*y+MCSI_ArregloPisosSuperior[C][D]
            pigment   { blue 1.0 green C red D/2 }
          }
          sphere      {
            0 , 0.04
            translate 0.04*y+MCSI_ArregloPisosInferior[C][D]
            pigment   { blue 1.0 green C red D/2 }
          }
          #local D    = D+1;
        #end
        #local C      = C+1;
      #end      
      translate <-1.5, 0.0, -3.0>
    }          


Modificadores

La siguiente es la lista de los modificadores permitidos en la unidad.

    #declare MCSI_DefaultTexturaMadera      	= texture { ... }      
Textura principal a aplicar al mueble.

    #declare MCSI_DefaultTexturaMaderaBarata    = texture { ... }
Textura del interior del mueble.

    #declare MCSI_DefaultTexturaAgarradera     	= texture { ... }
Textura a aplicar a las agarraderas y bisagras.

    #declare MCSI_DefaultTexturaImpermeable    	= texture { ... }
Textura a aplicar a la cubierta impermeable del mueble inferior.

    #macro   MCSI_Agarradera()
Permite modificar la forma de la agarradera.  Para ubicar se puede visualizar como un cilindro orientado hacia Z-, similar a cylinder { 0, -z, 1 }.

    #declare MCSI_POV3_1			= off;
Si se activa con "on" produce simplificaciones que permiten su ejecución en la versión POVRay 3.1.  En algunas versiones de POVRay se activa automáticamente.  En esta versión no cumple ninguna función.

A manera de ejemplo del uso de los modificadores:

    #include "stdinc.inc"
    #include "stdcam.inc"
    #include "MCSI.inc"                 
    #include "textures.inc"
                     
    #declare MCSI_DefaultTexturaMadera          = texture       {
      pigment   { Yellow }
    }
    
    #declare MCSI_DefaultTexturaMaderaBarata    = texture       {
      average
      texture_map       {
        [ 0.5 MCSI_TexturaMaderaBarata ]
        [ 0.5 Rust                     ]
      }
    }   
    
    #declare MCSI_DefaultTexturaAgarradera      = texture       {
      pigment   { White }
    }        
    
    #declare MCSI_DefaultTexturaImpermeable     = texture       {
      pigment   { color Red*0.75+White*0.25 }
    }
    
    #macro MCSI_Agarradera()
      cylinder  {
        0       , -2*z    , 1
      }
    #end
                     
    object            {
      MCSI_MuebleCocina(on,90,90,0,0,90,0)               
      translate <-1.5, 0.0, -3.0>
    }          


Notas y Advertencias

Al redefinir las texturas, hay que tomar en cuenta que se le aplicarán varias transformaciones antes de su presentación final.  Esto podría complicar el proceso de diseño.

Se le aplica la textura principal a la parte posterior del mueble.  Esto contradice la costumbre en Costa Rica, de aplicar madera de calidad inferior a la zona posterior.

No debería utilizar la variable MCSI_ArregloPuertas después de un llamado a la macro principal MCSI_MuebleCocina().  No se garantiza compatibilidad a futuro.


Sugerencias de modificación


Sobre LibreN3D

Algo hace falta En la actualidad dedico casi unas dos horas todos los días, para desarrollar el programa de animación LibreN3D con el compilador FreePascal para FreeDOS.  El objetivo era en un origen, realizar animaciones de "baja" calidad, con progreso lento y paulatino. Desconocía en ese entonces del programa POV-Ray.  Creo que con ayuda de dicho proyecto, podría lograr mucho mejores resultados desde un principio.  Confío que para el 2020 pueda lograr animaciones completas de aceptable calidad.   En la actualidad, intento agregarle características elásticas a los objetos.  He tenido numerosos retrasos, así que todavía no funciona.  Lo siento...(8/mayo/2012), pero me siento muy seguro de que pronto lo lograré.  De momento, no tiene interface con el usuario, pero se encuentra en desarrollo como intérprete de renglón al estilo DOS.

Me sería de muchísima ayuda, que el grupo POV-Ray siguiera desarrollando la versión para DOS.   Los siguientes son enlaces que podrían ser de utilidad para el interesado en los proyectos FreePascal y FreeDOS.   Lamentablemente en la actualidad son altamente inestables, debido probablemente a dificultades con la adaptación al modo de 64 bits.
Logo FreeDOS...
Descarga sistema operativo FreeDOS
Logo FreePascal...
Descarga compilador FreePascal