Logo POVRay...
Instrucciones para "CJQS.inc" v1.0

Donación de Rafael Angel Campos Vargas, en el año 2019, a la Biblioteca de objetos de POV-Ray.  Este proyecto se encuentra actualmente suscrito a la patente LGPL;  para libre uso comercial y no comercial del software.

CC-GNU LGPL
The primary purpose of this collection is to make items publicly available under a common license that permits use, modification and re-distribution. To support this contributions are donated to the collection with consent for their use under the terms of the Creative Commons - Lesser General Purpose License (CC-GNU LGPL).
Chris Bartlett 2007

La versión actual v1.0 de "CJQS.inc" (CristaleriaJuegoQuimicaSupervisado) dibuja un erlenmeyer, tubo de ensayo y gotero para juego de química. Posee una macro para modificar las características principales, pero es muy poco flexible. Es compatible con POV-Ray 3.1.

Indice de página:

  1. Instalación de Archivos
  2. Instrucciones básicas
  3. Características del objeto
  4. Modificadores
  5. Notas y Advertencias
  6. Sugerencias de modificación
  7. Sobre LibreN3D

Instalación de Archivos

El procedimiento siguiente es completamente optativo, corresponde simplemente al estándard de la Biblioteca de objetos POV-Ray.
  1. Cree el subdirectorio "ObjectCollections".  Se sugiere un subdirectorio del folder POV-Ray, creado por el instalador en algunas versiones en la sección de documentos o bien en la de código.
  2. Copie el archivo "CJQS.inc" en dicho subdirectorio;  únicamente estos es necesario.  En cuanto a la documentación y demás puede colocarla si desea en el mismo subdirectorio, el estándar ha sido diseñado para evitar problemas de compatibilidad.
  3. Actualice los archivos buscados por POV-Ray, en algún archivo ini pertinente.  Por ejemplo "POVRay.ini";  agregue el comando Library_Path="C:\FDOS\POVRAY31\ObjectCollections"; o el que corresponda a su sistema operativo.  POV-Ray ofrece muchas formas de realizar esto.  Si no sabe cómo, probablemente convenga leer el manual de referencia en la sección "Command-line options".   Cada sistema operativo presenta sus propias variantes.
Nota:  El archivo de prueba "CJQS.pov" puede ejecutarse sin ningún proceso de instalación.  Unicamente debería estar ubicado en el mismo folder que "CJQS.inc".


Instrucciones básicas

Erlenmeyer
Muy fácil de usar, tan simple como incluir el archivo y ubicar los objetos requeridos.  El siguiente ejemplo ilustra el procedimiento básico.
    #if ( version >= 3.7 )
      #version 3.7;
    #end
    global_settings { assumed_gamma 1.0 }  

    #include "stdinc.inc"
    #include "stdcam.inc"
    #include "CJQS.inc"
    
    union       {
      object    { CJQS_Erlenmeyer( ) }
      object    { CJQS_TuboEnsayo( ) translate  0.04*x }
      object    { CJQS_Gotero( )     translate  0.06*x }
      translate         <-1.98,+1.64,-4.85>    
    }

La siguiente macro dibuja un erlenmeyer:

    #macro CJQS_Erlenmeyer( )

La siguiente macro dibuja un tubo de ensayo:

    #macro CJQS_TuboEnsayo( )

La siguiente macro dibuja un gotero:

    #macro CJQS_Gotero( )

Puede controlarse el dibujo del erlenmeyer con mayor detalle con la siguiente macro:

    #macro CJQS_ErlenmeyerDetalle( DiametroMayor, DiametroMenor,
        AltoErlenmeyer, AltoDiametroMayor, AltoDiametroMenor,
        GruesoVidrio, GruesoLinea, MaterialVidrio )   
DiametroMayor :
Diámetro mayor del erlenmeyer. Valor por defecto 46*L.
DiametroMenor :
Diámetro menor del erlenmeyer. Valor por defecto 16*L.
AltoErlenmeyer :
Alto del erlenmeyer. Valor por defecto 75*L.
AltoDiametroMayor :
Alto del diámetro mayor respecto a la base. Valor por defecto 9*L.
AltoDiametroMenor :
Alto del diámetro menor respecto a la base. Valor por defecto 54*L.
GruesoVidrio :
Grueso del vidrio del erlenmeyer. Valor por defecto 1*L.
GruesoLinea :
Para el grueso de la letra de inscripción. Valor por defecto 0.5*L.
MaterialVidrio :
Material del vidrio. Valor por defecto CJQS_MaterialVidrio.

Puede controlarse el dibujo del tubo de ensayo con mayor detalle con la siguiente macro:

    #macro CJQS_TuboEnsayoDetalle( AltoTubo,
        DiametroTubo, GruesoVidrio, MaterialVidrio )
AltoTubo :
Alto del tubo de ensayo. Valor por defecto 87*L.
DiametroTubo :
Diámetro principal del tubo. Valor por defecto 11*L.
GruesoVidrio :
Grueso del vidrio. Valor por defecto 0.85*L.
MaterialVidrio :
Material del vidrio. Valor por defecto CJQS_MaterialVidrio.

Puede controlarse el dibujo del gotero con mayor detalle con la siguiente macro:

    #macro CJQS_GoteroDetalle( DiametroGotero, LargoGotero,
        LargoHule, DiametroTapa, LargoTapa,
        GruesoVidrio, MaterialVidrio, MaterialHule, MaterialTapa )
DiametroGotero :
Diámetro del vidrio del gotero. Valor por defecto 5*L.
LargoGotero :
Largo total con el bulbo. Valor por defecto 62*L.
LargoHule :
Tamaño en Y del bulbo de succión. Valor por defecto 17*L.
DiametroTapa :
Diámetro de la tapilla plástica de unión. Valor por defecto 14*L.
LargoTapa :
Tamaño en Y de la tapilla plástica de unión. Valor por defecto 8*L.
GruesoVidrio :
Grueso del vidrio del erlenmeyer. Valor por defecto 1*L.
MaterialVidrio :
Material del vidrio. Valor por defecto CJQS_MaterialVidrio.
MaterialHule :
Material del bulbo de succión. Valor por defecto CJQS_MaterialHule.
MaterialTapa :
Material de la tapilla plástica de rosca. Valor por defecto CJQS_MaterialTapa.

El siguiente ejemplo dibuja los mismos objetos por defecto.

    #if ( version >= 3.7 )
      #version 3.7;
    #end
    global_settings { assumed_gamma 1.0 }  

    #include "stdinc.inc"
    #include "stdcam.inc"
    #include "CJQS.inc"
    
    union       {
      object    {
        CJQS_ErlenmeyerDetalle( 0.046, 0.016, 0.075, 0.009, 0.054, 
            0.001, 0.0005, CJQS_MaterialVidrio )
      }
      object    { 
        CJQS_TuboEnsayoDetalle( 0.087, 0.011, 0.00085, CJQS_MaterialVidrio )
        translate  0.04*x 
      }
      object    { 
        CJQS_GoteroDetalle( 0.005, 0.062, 0.017, 0.014, 0.008, 0.00085,
            CJQS_MaterialVidrio, CJQS_MaterialHule, CJQS_MaterialTapa )
        translate  0.06*x 
      }
      translate         <-1.98,+1.64,-4.85>    
    }


Características del objeto

Mis dibujos están en unidades mL o L (Lisa) según el contexto.  1 L equivale a 0.055063 pulgadas definido como 0.001 para POVRAY.  El erlenmeyer se encuentra contenido entre las siguientes coordenadas:
    Mínimo          = <-23,  0,-23>*L
    Máximo          = <+23,+75,+23>*L
    Mínimo          = <-DiametroMayor/2,              0, -DiametroMayor/2>
    Máximo          = <+DiametroMayor/2, AltoErlenmeyer, +DiametroMayor/2>

El fondo del recipiente descansa sobre el plano XZ, en el hemisferio Y+.

El tubo de ensayo se encuentra contenido entre las siguientes coordenadas:

    Mínimo          = <- 6,  0,- 6>*L
    Máximo          = <+ 6,+87,+ 6>*L
    Mínimo          = <-(DiametroTubo + GruesoVidrio)/2,        0,
                       -(DiametroTubo + GruesoVidrio)/2>
    Máximo          = <+(DiametroTubo + GruesoVidrio)/2, AltoTubo,
                       +(DiametroTubo + GruesoVidrio)/2>

El fondo del tubo de ensayo inmediatamente sobre el plano XZ, en el hemisferio Y+.

El gotero se encuentra contenido entre las siguientes coordenadas:

    Mínimo          = <- 7,  0,- 7>*L
    Máximo          = <+ 7,+62,+ 7>*L
    Mínimo          = <-DiametroTapa/2,          0, -DiametroTapa/2>
    Máximo          = <+DiametroTapa/2, AltoGotero, +DiametroTapa/2>

La punta del gotero ligeramente por encima del plano XZ, en el hemisferio Y+.

Se generan las siguientes declaraciones que no deberían modificarse.  Para su correcta modificación consulte la sección Modificadores.

CJQS_DefectoMaterialVidrio
Material para los instrumentos de vidrio.
CJQS_DefectoMaterialHule
Material para la goma de succión del gotero.
CJQS_DefectoMaterialTapa
Material para la pata sujetadora del gotero.
CJQS_ErlenmeyerInterior
Luego de llamar a la macro, se genera este object para el interior del erlenmeyer. Se sugiere utilizar con intersection para rellenar con líquido.
CJQS_TuboEnsayoInterior
Luego de llamar a la macro, se genera este object para el interior del tubo de ensayo. Se sugiere utilizar con intersection para rellenar con líquido.
CJQS_GoteroInterior
Luego de llamar a la macro, se genera este object para el interior del gotero. Se sugiere utilizar con intersection para rellenar con líquido.

El siguiente ejemplo ilustra un método simple para rellenar con líquido.

    #if ( version >= 3.7 )
      #version 3.7;
    #end
    global_settings { assumed_gamma 1.0 }  

    #include "stdinc.inc"
    #include "stdcam.inc"
    #include "CJQS.inc"
    
    union       {
      union     { 
        object { CJQS_Erlenmeyer( ) }
        intersection                {
          object  { CJQS_ErlenmeyerInterior }
          plane   { y, 0.02 } 
          pigment { Orange }
        }
      }
      union     { 
        object { CJQS_TuboEnsayo( ) }
        intersection                {
          object  { CJQS_TuboEnsayoInterior }
          plane   { y, 0.03 } 
          pigment { Orange }
        }
        translate  0.04*x 
      }
      union     { 
        object { CJQS_Gotero( )     }
        intersection                {
          object  { CJQS_GoteroInterior }
          plane   { y, 0.01 } 
          pigment { Orange }
        }
        translate  0.06*x 
      }
      translate         <-1.98,+1.64,-4.85>    
    }


Modificadores

La siguiente es la lista de los modificadores permitidos en la unidad. Cuando se indique, será el valor establecido por defecto.

    #declare CJQS_LetraVisible			= on;
Cuando activa on dibuja las marcas en el erlenmeyer. Si se desactiva off no las dibuja.

    #declare CJQS_PigmentLetra			= pigment { White }
Cuando aplique se utilizará este pigment para las marcas del erlenmeyer.

    #declare CJQS_MaterialVidrio		=
		material  { CJQS_DefectoMaterialVidrio			}
Material para los instrumentos de vidrio.

    #declare CJQS_MaterialHule			=
		material  { CJQS_DefectoMaterialHule			}
Material para la goma de succión del gotero.

    #declare CJQS_MaterialTapa			=
		material  { CJQS_DefectoMaterialTapa			}
Material para la tapa sujetadora del gotero.

El siguiente ejemplo ilustra el uso de los modificadores:

    #if ( version >= 3.7 )
      #version 3.7;
    #end
    global_settings { assumed_gamma 1.0 }  

    #include "stdinc.inc"
    #include "stdcam.inc"
    #include "CJQS.inc"
    #include "textures.inc"
    
    #declare CJQS_MaterialVidrio    = M_Green_Glass  
    #declare CJQS_MaterialHule      = M_Glass
    #declare CJQS_MaterialTapa      = M_Ruby_Glass  
    
    #declare CJQS_PigmentLetra      = pigment { Black }
    
    union       {
      object    { CJQS_Erlenmeyer( ) }    
      #declare CJQS_LetraVisible    = off;
      object    { CJQS_Erlenmeyer( ) translate -0.05*x }    
      object    { CJQS_TuboEnsayo( ) translate  0.04*x }
      object    { CJQS_Gotero( )     translate  0.06*x }
      translate         <-1.98,+1.64,-4.85>    
    }


Notas y Advertencias

Al variar los parámetros debe hacerlo en forma consistente para lograr buenos resultados.

El gotero se encuentra algo por encima del plano XZ pero no hay contacto.

Las superficies interiores son algo menores a lo real para evitar efectos de renderizado desagradables.


Sugerencias de modificación


Sobre LibreN3D

Algo hace falta En la actualidad dedico casi unas dos horas todos los días, para desarrollar mis proyectos de animación con el compilador FreePascal para FreeDOS.  Mi propuesta original fue filmar animaciones de "baja" calidad, con progreso lento y paulatino. Desconocía en ese entonces del programa POV-Ray.  Creo que con ayuda de dicho proyecto, podría lograr mucho mejores resultados desde un principio.  Confío que dentro de algunos años pueda lograr animaciones completas de aceptable calidad.   En la actualidad, intento agregarle características elásticas a los objetos.  He tenido numerosos retrasos, así que todavía no funciona.  Lo siento...(24/enero/2019), pero me siento muy seguro de que pronto lo lograré.  De momento, no tiene interface con el usuario, pero se encuentra en desarrollo como intérprete de renglón al estilo DOS.

Me sería de muchísima ayuda, que el grupo POV-Ray siguiera desarrollando la versión para DOS.   Los siguientes son enlaces que podrían ser de utilidad para el interesado en los proyectos FreePascal y FreeDOS.
Logo FreeDOS...
Descarga sistema operativo FreeDOS
Logo FreePascal...
Descarga compilador FreePascal